|  |  |  |
| --- | --- | --- |
| # | Expression | Predict |
| 1 | <program> → <global> Lead : Start <statements> End . <taskdef> | Let, Array, Object, Var, Task, Lead |
| 2 | <global> → <global\_choice> . <global> | Let, Array, Object, Var, Task |
| 3 | <global> → λ | Lead |
| 4 | <global\_choice> → <let\_global> | Let |
| 5 | <global\_choice> → <vardec> | Var |
| 6 | <global\_choice> → <array> | Array |
| 7 | <global\_choice> → <task> | Task |
| 8 | <global\_choice> → <object> | Object |
| 9 | <datatype> → Int id | Int |
| 10 | <datatype> → Double id | Double |
| 11 | <datatype> → Char id | Char |
| 12 | <datatype> → String id | String |
| 13 | <datatype> → Boolean id | Boolean |
| 14 | <let\_global> → Let id is <values> | Let |
| 15 | <values> → intlit | intlit |
| 16 | <values> → doublelit | doublelit |
| 17 | <values> → stringlit | stringlit |
| 18 | <values> → charlit | charlit |
| 19 | <values> → boollit | boollit |
| 20 | <vardec> → Var <vardtype> | Var |
| 21 | <vardtype> → Int id <varinitINT> <vartailINT> | Int |
| 22 | <vardtype> → Double id <varinitDOUBLE> <vartailDOUBLE> | Double |
| 23 | <vardtype> → Char id <varinitCHAR> <vartailCHAR> | Char |
| 24 | <vardtype> → String id <varinitSTRING> <vartailSTRING> | String |
| 25 | <vardtype> → Boolean id <varinitBOOLEAN> <vartailBOOLEAN> | Boolean |
| 26 | <varinitINT> → is <mathopINT> | is |
| 27 | <varinitINT> → λ | ;, . |
| 28 | <varinitDOUBLE> → is <mathopDOUBLE> | is |
| 29 | <varinitDOUBLE> → λ | ;, . |
| 30 | <varinitCHAR> → is <valueCHAR> | is |
| 31 | <varinitCHAR> → λ | ;, . |
| 32 | <varinitSTRING> → is <valueSTRING> | is |
| 33 | <varinitSTRING> → λ | ;, . |
| 34 | <varinitBOOLEAN> → is <valueBOOLEAN> | is |
| 35 | <varinitBOOLEAN> → λ | ;, . |
| 36 | <vartailINT> → ; id <varinitINT> <vartailINT> | ; |
| 37 | <vartailINT> → λ | . |
| 38 | <vartailDOUBLE> → ; id <varinitDOUBLE> <vartailDOUBLE> | ; |
| 39 | <vartailDOUBLE> → λ | . |
| 40 | <vartailCHAR> → ; id <varinitCHAR> <vartailCHAR> | ; |
| 41 | <vartailCHAR> → λ | . |
| 42 | <vartailSTRING> → ; id <varinitSTRING> <vartailSTRING> | ; |
| 43 | <vartailSTRING> → λ | . |
| 44 | <vartailBOOLEAN> → ; id <varinitBOOLEAN> <vartailBOOLEAN> | ; |
| 45 | <vartailBOOLEAN> → λ | . |
| 46 | <valueCHAR> → charlit | charlit |
| 47 | <valueCHAR> → id <id\_tail> | id |
| 48 | <valueSTRING> → stringlit | stringlit |
| 49 | <valueSTRING> → id <id\_tail> | id |
| 50 | <valueBOOLEAN> → boollit | boollit |
| 51 | <valueBOOLEAN> → id <id\_tail> | id |
| 52 | <id\_tail> → <ids\_tail> | @, [ |
| 53 | <id\_tail> → ( <task\_param> ) | ( |
| 54 | <ids\_tail> → <id\_choices> | @, [ |
| 55 | <ids\_tail> → λ | =, ++, --, ;, ., +, -, \*, /, %, ) |
| 56 | <id\_choices> → @ <elements> | @ |
| 57 | <id\_choices> → [ <index> ] <index\_tail> | [ |
| 58 | <task\_param> → <value> <task\_param\_tail> | intlit, doublelit, stringlit, charlit, boollit, id |
| 59 | <task\_param> → λ | ) |
| 60 | <task\_param\_tail> → ; <task\_param> | ; |
| 61 | <task\_param\_tail> → λ | ) |
| 62 | <value> → <values> | intlit, doublelit, stringlit, charlit, boollit |
| 63 | <value> → <elements> | id |
| 64 | <index> → <index\_value> <indexop> | id, intlit |
| 65 | <indexop> → <add\_min> <index\_value> | +, - |
| 66 | <add\_min> → + | + |
| 67 | <add\_min> → - | - |
| 68 | <index\_value> → id | id |
| 69 | <index\_value> → intlit | intlit |
| 70 | <index\_tail> → [ <index> ] |  |
| 71 | <elements> → id <elements\_tail> | id |
| 72 | <elements\_tail> → @ <elements> | @ |
| 73 | <elements\_tail> → λ | Start, ;, ), ,, ==, !=, >, >=, <, <=, =, ++, --, ., +, -, \*, /, % |
| 74 | <array> → Array <datatype> of intlit <size\_tail> | Array |
| 75 | <size\_tail> → by intlit | by |
| 76 | <size\_tail> → λ | . |
| 77 | <task> → Task <return\_type> <parameters> | Task |
| 78 | <return\_type> → <datatype> | Int, Double, Char, String, Boolean |
| 79 | <return\_type> → Null id | Null |
| 80 | <parameters> → ( <datatype> <param\_tail> ) | ( |
| 81 | <parameters> → λ | . |
| 82 | <param\_tail> → ; <datatype> <param\_tail> | ; |
| 83 | <param\_tail> → λ | ) |
| 84 | <object> → Object id Start <object\_elem> End <object\_var> | Object |
| 85 | <object\_elem> → Var <datatype> . <object\_elem\_tail> | Var |
| 86 | <object\_elem> → Object id id . <object\_elem\_tail> | Object |
| 87 | <object\_elem\_tail> → <object\_elem> | Var, Object |
| 88 | <object\_elem\_tail> → λ | End |
| 89 | <object\_var> → id <object\_var\_tail> | id |
| 90 | <object\_var> → λ | . |
| 91 | <object\_var\_tail> → ; <object\_var> | ; |
| 92 | <object\_var\_tail> → λ | . |
| 93 | <statements> → <functions> . <statements> | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id |
| 94 | <statements> → λ | ., Stop, End |
| 95 | <functions> → <vardec> | Var |
| 96 | <functions> → <array> | Array |
| 97 | <functions> → Object id id | Object |
| 98 | <functions> → <io\_statement> | Read, Say |
| 99 | <functions> → <pre\_incdec> | ++, -- |
| 100 | <functions> → Clear | Clear |
| 101 | <functions> → <option> | Option |
| 102 | <functions> → <IfOtherwise> | If |
| 103 | <functions> → <loopstate> | Until, Do, For |
| 104 | <functions> → <id\_stmt> | id |
| 105 | <io\_statement> → Read id <ids\_tail> | Read |
| 106 | <io\_statement> → Say <output\_statement> | Say |
| 107 | <output\_statement> → stringlit <concat> | stringlit |
| 108 | <output\_statement> → <id\_choices> <concat> | @, |
| 109 | <concat> → , <output\_statement> | , |
| 110 | <concat> → λ | . |
| 111 | <pre\_incdec> → ++ id | ++ |
| 112 | <pre\_incdec> → -- id | -- |
| 113 | <option> → Option <elements> Start State <option\_choices> | Option |
| 114 | <option\_choices> → <optionINT> | intlit |
| 115 | <option\_choices> → <optionCHAR> | charlit |
| 116 | <option\_choices> → <optionSTRING> | stringlit |
| 117 | <optionINT> → intlit : <statements> Stop . <stateINT> <default> End | intlit |
| 118 | <optionCHAR> → charlit : <statements> Stop . <stateCHAR> <default> End | charlit |
| 119 | <optionSTRING> → stringlit : <statements> Stop . <stateSTRING> <default> End | stringlit |
| 120 | <stateINT> → State intlit : <statements> Stop . <stateINT> | State |
| 121 | <stateINT> → λ | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id, Default |
| 122 | <stateCHAR> → State charlit : <statements> Stop . <stateCHAR> | State |
| 123 | <stateCHAR> → λ | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id, Default |
| 124 | <stateSTRING> → State stringlit : <statements> Stop . <stateSTRING> | State |
| 125 | <stateSTRING> → λ | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id, Default |
| 126 | <default> → Default : <statements> | Default |
| 127 | <default> → λ | End |
| 128 | <conditions> → <condition\_choices> | id, intlit, doublelit, stringlit, charlit, boollit |
| 129 | <conditions> → <negate> ( <condition\_choices> ) <logOp\_tail> | !, ( |
| 130 | <condition\_choices> → id <condition\_ids> <relOp> <condition\_choices> | id |
| 131 | <condition\_choices> → <values> <relOp> <condition\_choices> | intlit, doublelit, stringlit, charlit, boollit |
| 132 | <condition\_ids> → <id\_choices> | @, |
| 133 | <condition\_ids> → ( <task\_param> ) | ( |
| 134 | <logOp\_tail> → <logOp> <logOp\_choices> <logOp\_tail> | &&, || |
| 135 | <logOp\_tail> → λ | &&, ||, ) |
| 136 | <logOp\_choices> → <negate> ( <condition\_choices> ) | !, ( |
| 137 | <logOp\_choices> → boollit <logOp\_tail> | boollit |
| 138 | <relOp> → == | == |
| 139 | <relOp> → != | != |
| 140 | <relOp> → > | > |
| 141 | <relOp> → >= | >= |
| 142 | <relOp> → < | < |
| 143 | <relOp> → <= | <= |
| 144 | <logOp> → && | && |
| 145 | <logOp> → || | || |
| 146 | <negate> → ! | ! |
| 147 | <negate> → λ | ( |
| 148 | <IfOtherwise> → If ( <conditions> ) <cond\_loop> <or> <otherwise> EndIf | If |
| 149 | <or> → Or ( <conditions> ) <cond\_loop> <or> | Or |
| 150 | <or> → λ | (, id, intlit, doublelit, stringlit, charlit, boollit, !, Otherwise |
| 151 | <otherwise> → Otherwise <cond\_loop> <control> | Otherwise |
| 152 | <otherwise> → λ | EndIf |
| 153 | <cond\_loop> → <functions> . <control> <cond\_loop> | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id |
| 154 | <cond\_loop> → λ | Loop, LoopIf, Skip, Stop, Or, (, id, intlit, doublelit, stringlit, charlit, boollit, !, ), EndIf, Otherwise |
| 155 | <control> → Skip . | Skip |
| 156 | <control> → Stop . | Stop |
| 157 | <control> → λ | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id, Loop, LoopIf, Skip, Stop, Or, (, intlit, doublelit, stringlit, charlit, boollit, !, ), EndIf, Otherwise |
| 158 | <loopstate> → Until ( <conditions> ) <cond\_loop> Loop | Until |
| 159 | <loopstate> → Do <cond\_loop> LoopIf ( <conditions> ) | Do |
| 160 | <loopstate> → For ( <initialize> ; <cond> ; <incdecvar> ) <cond\_loop> Loop | For |
| 161 | <initialize> → id = <init\_choices> | id |
| 162 | <initialize> → λ | ; |
| 163 | <init\_choices> → intlit | intlit |
| 164 | <init\_choices> → id | id |
| 165 | <cond> → <init\_choices> <relOp> <init\_choices> | intlit, id |
| 166 | <cond> → λ | ; |
| 167 | <incdecvar> → <incdec> id | ++, -- |
| 168 | <incdecvar> → id <incdec> | id |
| 169 | <id\_stmt> → id <id\_stmt\_tail> | id |
| 170 | <id\_stmt\_tail> → <ids\_tail> = <initvalues> | @, , = |
| 171 | <id\_stmt\_tail> → ( <task\_param> ) | ( |
| 172 | <initvalues> → <mathopNUM> | (, intlit, doublelit, id, ++, -- |
| 173 | <initvalues> → charlit | charlit |
| 174 | <initvalues> → stringlit | stringlit |
| 175 | <initvalues> → boollit | boollit |
| 176 | <mathopINT> → <intvalue> <mathopINT\_tail> | intlit, id, ++, -- |
| 177 | <mathopINT> → ( <mathopINT> ) <mathopINT\_tail> | ( |
| 178 | <mathopDOUBLE> → <doublevalue> <mathopDOUBLE\_tail> | doublelit, id, ++, -- |
| 179 | <mathopDOUBLE> → ( <mathopDOUBLE> ) <mathopDOUBLE\_tail> | ( |
| 180 | <mathopNUM> → <numvalue> <mathopNUM\_tail> | intlit, doublelit, id, ++, -- |
| 181 | <mathopNUM> → ( <mathopNUM> ) <mathopNUM\_tail> | ( |
| 182 | <intvalue> → intlit | intlit |
| 183 | <intvalue> → <exprID> | id, ++, -- |
| 184 | <doublevalue> → doublelit | doublelit |
| 185 | <doublevalue> → <exprID> | id, ++, -- |
| 186 | <numvalue> → intlit | intlit |
| 187 | <numvalue> → doublelit | doublelit |
| 188 | <numvalue> → <exprID> | id, ++, -- |
| 189 | <exprID> → id <id\_tail> <incdec\_null> | id |
| 190 | <exprID> → <pre\_incdec> <id\_tail> | ++, -- |
| 191 | <mathopINT\_tail> → <operators> <mathopINT> | +, -, \*, /, % |
| 192 | <mathopINT\_tail> → λ | ), ;, . |
| 193 | <mathopDOUBLE\_tail> → <operators> <mathopDOUBLE> | +, -, \*, /, % |
| 194 | <mathopDOUBLE\_tail> → λ | ), ;, . |
| 195 | <mathopNUM\_tail> → <operators> <mathopNUM> | +, -, \*, /, % |
| 196 | <mathopNUM\_tail> → λ | ), . |
| 197 | <operators> → + | + |
| 198 | <operators> → - | - |
| 199 | <operators> → \* | \* |
| 200 | <operators> → / | / |
| 201 | <operators> → % | % |
| 202 | <incdec> → ++ | ++ |
| 203 | <incdec> → -- | -- |
| 204 | <incdec\_null> → <incdec> | ++, -- |
| 205 | <incdec\_null> → λ | +, -, \*, /, %, ), ., ; |
| 206 | <taskdef> → Task <return\_id> End . <taskdef> | Task |
| 207 | <taskdef> → λ | # |
| 208 | <return\_id> → Int id : <taskbody> Response <returnINT> . | Int |
| 209 | <return\_id> → Double id : <taskbody> Response <returnDOUBLE> . | Double |
| 210 | <return\_id> → Char id : <taskbody> Response <returnCHAR> . | Char |
| 211 | <return\_id> → String id : <taskbody> Response <returnSTRING> . | String |
| 212 | <return\_id> → Boolean id : <taskbody> Response <returnBOOLEAN> . | Boolean |
| 213 | <return\_id> → Null id : <taskbody> | Null |
| 214 | <taskbody> → Start <taskbodytail> | Start |
| 215 | <taskbodytail> → <statements> . | Object, Clear, Var, Read, Say, Option, Until, Do, For, Array, If, ++, --, id, . |
| 216 | <returnINT> → intlit | intlit |
| 217 | <returnINT> → id <returntail> | id |
| 218 | <returnDOUBLE> → doublelit | doublelit |
| 219 | <returnDOUBLE> → id <returntail> | id |
| 220 | <returnCHAR> → charlit | charlit |
| 221 | <returnCHAR> → id <returntail> | id |
| 222 | <returnSTRING> → stringlit | stringlit |
| 223 | <returnSTRING> → id <returntail> | id |
| 224 | <returnBOOLEAN> → boollit | boollit |
| 225 | <returnBOOLEAN> → id <returntail> | id |
| 226 | <returntail> → ( <task\_param> ) | ( |
| 227 | <returntail> → <elements> | id |
| 228 | <returntail> → λ | . |
| 229 | <StartProgram> → <program> # | Lead, Let, Array, Object, Var, Task |